home *** CD-ROM | disk | FTP | other *** search
/ PCMania 73 / PCMania CD73_1.iso / pcmania / render73 / Taller / castli17 / LATERAL.INC < prev    next >
Text File  |  1998-01-04  |  21KB  |  625 lines
  1. /* Este fichero es la versión recortada de town.inc, el  cual  es  parte  de
  2.    Castlib,  una  libreria  de  formas para la creación de castillos con POV
  3.    3.0.   La  presente  versión  de  este  "producto"  puede  ser  utilizada
  4.    libremente por cualquiera, pero  dicho  uso  implica la aceptación de las
  5.    siguientes condiciones:
  6.    1) Si alguien emplea alguna de las  estructuras  de  Castlib  1.7  debera
  7.    indicarlo  asi  al  principio  de  su fichero escenico citando tambien el
  8.    nombre de su autor.
  9.    2) Si alguien realiza alguna modificación sobre los ficheros que componen
  10.    Castlib 1.7, debera citar el producto original y su procedencia e indicar
  11.    que lo utilizado es una mutación de Castlib.
  12.    3) Este producto no es shareware sino de PAGO.  Si lo  utilizas  y  algun
  13.    dia, casualmente o no, topas con el autor de Castlib, quedaras obligado a
  14.    invitar a dicho autor a  una caña mientras le explicas como has utilizado
  15.    su producto.
  16.    4)  El  autor  rechaza  cualquier  responsabilidad por cualquier desastre
  17.    informatico, neurologico, o de  cualquier  otro  tipo  que el uso de este
  18.    producto pudiera ocasionar a cualquier ser  pensante  con  una  capacidad
  19.    mental  superior a la de una piedra.  Se entiende asimismo que el usuario
  20.    renuncia a cualquier pretensión de  reclamación, ahora y siempre, en este
  21.    o en cualquier otro universo (paralelo o no), sin excepción  espacial  ni
  22.    temporal, y liberando al autor en parte y en todo de cualquier obligación
  23.    futura.
  24.    5)  La  clausula  4  tambien  se  aplica  a  las entidades integrantes de
  25.    cualquier universo o entorno  virtual  simulado  en cualquier sistema con
  26.    capacidad de procesamiento superior al de un abaco.
  27.    6)  El  uso  de este producto y el incumplimiento de estas clausulas sera
  28.    castigado con medidas judiciales y ostracismo en PCmania. */
  29.  
  30. // ---------------------------------------------------
  31. // PANELES CUADRADOS PARA LAS CASAS            
  32. // esta viga basica esta en pos. vertical
  33. //#declare viga=box{<-1,-25,-2>,<1,25,0> texture{T_Wood14 scale<10,10,10>} }
  34. #declare viga=box{<-1,-25,-2>,<1,25,0> texture{T_Wood17 scale<5,5,5>} }
  35. //#declare tejas = texture { T_Wood12 scale<2,2,2>}
  36. #declare tejas = texture { T_Wood14 scale<.25,.25,.25>}
  37. #declare panelb=union{
  38.     box{<-25,0,0>,<25,50,2> 
  39.         texture{texcastle1}}
  40.     object{viga rotate z*90 translate <0,50,0>}
  41.     object{viga rotate z*90 translate <0,2,0>}
  42.     object{viga translate <-25,25,0>}
  43.     object{viga translate <25,25,0>}
  44. }
  45. // dos vigas cruzadas en diagonal
  46. #declare panel1=union{
  47.     object{panelb}
  48.     object{viga scale <1.5,1.33,1> rotate z*45 translate <0,25,-0.2>}
  49.     object{viga scale <1.5,1.33,1> rotate z*-45 translate <0,25,-0.3>}
  50.     }
  51. // una viga en diagonal
  52. #declare panel2=union{
  53.     object{panelb}
  54.     object{viga scale <1.5,1.33,1> rotate z*45 translate <0,25,-0.2>}
  55.     }
  56. // una viga en diagonal
  57. #declare panel3=union{
  58.     object{panelb}
  59.     object{viga scale <1.5,1.33,1> rotate z*-45 translate <0,25,-0.2>}
  60.     }
  61. // dos vigas verticales
  62. #declare panel4=union{
  63.     object{panelb}
  64.     object{viga translate <-10,25,0>}
  65.     object{viga translate <10,25,0>}
  66.     }
  67. //una viga horizontal baja y dos ventanas de tipo 1
  68. #declare panel5=union{
  69.     difference{
  70.         object{panelb}
  71.         object{recven1 translate <-12,25,-1>}
  72.         object{recven1 translate <12,25,-1>}
  73.     }
  74.     object{marcove1 translate <-12,25,3.75> }
  75.     object{marcove1 translate <12,25,3.75> }
  76.     object{viga rotate z*90 translate <0,15,0>}
  77. }
  78. //dos ventanitas cuadradas y una viga horizontal
  79. #declare panel6=union{
  80.     difference{
  81.         object{panelb}
  82.         box{<-5,15,-10>,<5,25,10> translate <-9,0,0>}
  83.         box{<-5,15,-10>,<5,25,10> translate <9,0,0>}
  84.     }
  85.     box{<-4,12,-3>,<4,15,0> translate <-9,0,0> texture{textmur1}}
  86.     box{<-4,12,-3>,<4,15,0> translate <9,0,0> texture{textmur1}}
  87.     object{viga rotate z*90 translate <0,37,0>}
  88.     }
  89. // con puerta
  90. #declare panel7=union{
  91.     difference{
  92.         object{panelb}
  93.         object{recpuer1}
  94.     }
  95.     object{puerta translate<0,0,3>}
  96. }
  97. // con puerta y dos vigas verticales
  98. #declare panel8=union{
  99.     object{panel7}
  100.     object{viga translate <-14,25,0>}
  101.     object{viga translate <14,25,0>}
  102. }
  103. // con puerta y ventanitas tipo 1
  104. #declare panel9=union{
  105.     difference{
  106.         object{panelb}
  107.         object{recpuer1}
  108.         object{recven1 translate <-12,25,-1>}
  109.         object{recven1 translate <12,25,-1>}
  110.     }
  111.     object{puerta translate<0,0,3>}
  112.     object{marcove1 translate <-12,25,3.75>}
  113.     object{marcove1 translate <12,25,3.75>}
  114. }
  115. // con puerta a la izq. y ventanita cuadrada a la der.
  116. #declare panel10=union{
  117.     difference{
  118.         object{panelb}
  119.         object{recpuer1 translate <-14,0,0>}
  120.         box{<-5,30,-10>,<5,40,10> translate <12,0,0>}
  121.     }
  122.     object{puerta translate<-14,0,3>}
  123.     box{<-4,27,-3>,<4,30,0> translate <12,0,0> texture{textmur1}}
  124. }
  125. // con puerta a la izq. y ventanita tipo 1 a la der.
  126. #declare panel11=union{
  127.     difference{
  128.         object{panelb}
  129.         object{recpuer1 translate <-14,0,0>}
  130.         object{recven1 translate <12,25,-1>}
  131.     }
  132.     object{puerta translate<-14,0,3>}
  133.     object{marcove1 translate <12,25,3.75> }
  134. }
  135. // con puerta a la izq., ventanita tipo 1 a la der. y viga diagonal
  136. #declare panel12=union{
  137.     object{panel11}
  138.     object{viga scale <1.5,1.33,1> rotate z*45 translate <0,25,-0.2>}
  139. }    
  140. //dos ventanitas tipo 1 a la altura del 1er piso
  141. #declare panel13=union{
  142.     difference{
  143.         object{panelb}
  144.         object{recven1 translate <-12,25,-1>}
  145.         object{recven1 translate <12,25,-1>}
  146.     }
  147.     object{marcove1 translate <-12,25,3.75> }
  148.     object{marcove1 translate <12,25,3.75> }
  149. }
  150. // dos vigas verticales
  151. #declare panel14=union{
  152.     difference{
  153.         object{panelb}
  154.         object{recven1 translate <0,25,-1>}
  155.     }
  156.     object{marcove1 translate <0,25,3.75> }
  157.     object{viga translate <-14,25,0>}
  158.     object{viga translate <14,25,0>}
  159. }
  160.  
  161.  
  162.  
  163. // ---------------------------------------------------
  164. // PANELES DIAGONALES PARA LOS TEJADOS DE LAS CASAS
  165. // con vigas diagonales
  166. #declare rectej45=union{
  167.     plane{y,0 inverse translate<25,0,0> rotate z*63 translate<-25,0,0> }
  168.     plane{y,0 inverse translate<25,0,0> rotate z*63 translate<-25,0,0> rotate y*180}
  169. }
  170. #declare paneld1=difference{
  171.     union{
  172.         box{<-25,0,0>,<25,50,2>}
  173.         object{viga translate<0,25,0>}
  174.         object{viga scale <1.5,1.33,1> rotate z*45 translate <-25,25,-0.2>}
  175.         object{viga scale <1.5,1.33,1> rotate z*-45 translate <25,25,-0.3>}
  176. //        pigment{ image_map{tga "piedra2.tga" }
  177. //                 translate <-.5,-.5,0> scale <14,14,1> }
  178.         texture{texcastle1}
  179.         }
  180.     object{rectej45}
  181. }
  182. // con ventana de tipo 1
  183. #declare paneld2=union{
  184.     difference{
  185.         box{<-25,0,0>,<25,50,2>}
  186.         object{rectej45}
  187.         object{recven1 translate <0,12,-1>}
  188. //        pigment{ image_map{tga "piedra2.tga" }
  189. //                 translate <-.5,-.5,0> scale <14,14,1> }
  190.         texture{texcastle1}
  191.         }    
  192.     object{marcove1 translate <0,12,3.75> }
  193. }
  194. // con puerta (habra escaleras)
  195. #declare paneld3=union{
  196.     difference{
  197.         box{<-25,0,0>,<25,50,2>}
  198.         object{rectej45}
  199.         object{recpuer1}
  200. //        pigment{ image_map{tga "piedra2.tga" }
  201. //                 translate <-.5,-.5,0> scale <14,14,1> }
  202.         texture{texcastle1}
  203.         }    
  204.     object{puerta translate<0,0,3>}
  205. }
  206. // panel diag. para lado izq.
  207. #declare paneld4=difference{
  208.     object{panel2}
  209.     plane{y,0 inverse rotate z*45 translate <-25,0,0>}
  210. }
  211. // panel diag. para lado der.
  212. #declare paneld5=difference{
  213.     object{panel3}
  214.     plane{y,0 inverse rotate z*45 translate <-25,0,0> rotate y*180}
  215. }
  216. // panel doble ( 4+5 ) con ventana central (desde -50X a +50X)
  217. #declare paneld6=union{
  218.     difference{
  219.         union{
  220.             object{paneld4 translate <-25,0,0>}
  221.             object{paneld5 translate <25,0,0>}
  222.             }
  223.         object{recven1 translate <0,15,-1>}
  224.         }
  225.     object{marcove1 translate <0,15,3.75> }
  226. }
  227.  
  228.  
  229. // ---------------------------------------------------
  230. // MACROS DE TEJADOS DE LAS CASAS
  231.  
  232. #declare irectej1=difference{box{<-32,0,-31>,<33,50,31>
  233.     translate<25,0,0> rotate z*63 translate<-25,0,0> }
  234.     plane{y,51 inverse}
  235.     texture{tejas}
  236. }
  237. #declare rectej1=union{
  238.     object{irectej1}
  239.     object{irectej1 rotate y*180}
  240. } 
  241. #declare mtej1=difference{
  242.     object{irectej1}
  243.     box{<-40,0,-40>,<40,60,40> translate<25,0,0> rotate z*63 translate<-28,0,0>}
  244. }
  245. // tejado para "casas" de 5 metros de ancho
  246. #declare tejado1=union{
  247.     object{mtej1}
  248.     object{mtej1 rotate y*180}
  249.     texture{tejas}
  250. }    
  251. // tejado de 45 grados
  252. #declare irectej2=difference{box{<-41,0,-31>,<50,50,31>
  253.     rotate z*45 translate<0,25,0>}
  254.     plane{y,51 inverse}
  255.     texture{tejas}
  256. }
  257. #declare rectej2=union{
  258.     object{irectej2}
  259.     object{irectej2 rotate y*180}
  260. }
  261. // tejado para partes adosadas
  262. #declare mtej2=difference{
  263.     object{irectej2}
  264.     box{<-50,0,-40>,<60,60,40> rotate z*45 translate<-3,25,0> }
  265.     texture{tejas}
  266. }
  267.  
  268. // ---------------------------------------------------
  269. //ESCALERAS
  270. /*  Este  tramo  de escaleras se usa para alcanzar las puertas colocadas a 5
  271.    metros de altura (de las casas).  Sube  de der.  a izq., Tiene 1.5 metros
  272.    de ancho y 5 metros de largo.  Consta de 25 peldaños */
  273. #declare escal5m= union{
  274.     #declare pel=0
  275.     #declare alt=50
  276.     #declare xpel=-5
  277.     #while (pel!=20)
  278. //        box{<-25,alt-2.5,-15>,<xpel,alt,0>}
  279.         box{<-25,alt-2.5,-7.5>,<xpel,alt,7.5>}
  280.         #declare alt=alt-2.5
  281.         #declare pel=pel+1
  282.         #declare xpel=xpel+2.5
  283.     #end    
  284. //    pigment{image_map{tga "piedra22.tga" map_type 0} scale <14,14,1>}
  285. }
  286.  
  287. #declare escal5=merge{
  288.     difference{
  289.         object{escal5m}
  290.         box{<-26,-1,-7.49>,<xpel,51,7.49>}
  291. //        pigment{image_map{tga "piedra22.tga" map_type 0} scale <14,14,1>}
  292.         }
  293.     intersection{
  294.         object{escal5m}
  295.         box{<-26,-1,-7.49>,<xpel,51,7.49>}
  296. //        pigment{image_map{tga "piedra22.tga" map_type 0} scale <14,14,1>
  297. //                rotate x*90}
  298.         }
  299.     translate<0,0,-7.5>
  300. }
  301.  
  302. //la misma escalera con puerta
  303. #declare escal51=union{
  304.     difference{
  305.         object{escal5}
  306.         object{recpuer1 translate<-12,0,-12>}
  307.         }        
  308.     object{puerta translate<-12,0,-12>}
  309. }
  310. //idem. con arco (en esquinas)
  311. #declare escal52=union{
  312.     difference{
  313.         object{escal5}
  314.         object{recpuer1 translate<0,-10,0> scale <1.3,2.5,5>
  315.                         translate<-14,10,-12>}
  316.         object{recpuer1 translate<0,-10,0> scale <1.3,2.5,1> rotate y*90
  317.                         translate<-22,10,-4>}
  318.         }        
  319.     object{marcopu translate<0,-10,0> scale <1.3,2.5,.5> translate<-14,10,-14>}
  320.     difference{
  321.         object{marcopu translate<0,-10,0> scale <1.3,2.5,.5> rotate y*90
  322.                        translate<-24,10,-4>}
  323.         plane{z,0 inverse texture{textmur1} }
  324.         }
  325. }
  326.  
  327. // ---------------------------------------------------
  328. // ahora, usando las "plantas", crear ESTRUCTURAS LATERALES y COLGANTES
  329. #declare macb1=union{
  330.     object{panel9 translate<-25,0,-25>}   
  331.     object{panel5 translate<25,0,-25>}   
  332.     object{panel4 rotate y*90 translate<-50,0,0>}
  333. }
  334. #declare planta1=union{
  335.     object{macb1}       
  336.     object{macb1 rotate y*180}
  337. }
  338. #declare macb2=union{
  339.     object{panel8 translate<-25,0,-25>}   
  340.     object{panel13 translate<25,0,-25>}   
  341.     object{panel14 rotate y*90 translate<-50,0,0>}
  342. }
  343. #declare planta2=union{
  344.     object{macb2}       
  345.     object{macb2 rotate y*180}
  346. }
  347. #declare macb6=union{
  348.     object{panel5 translate<-25,0,-25>}   
  349.     object{panel5 translate<25,0,-25>}   
  350.     object{panel9 rotate y*90 translate<-50,0,0>}
  351. }
  352. #declare planta3=union{
  353.     object{macb6}       
  354.     object{macb6 rotate y*180}
  355. }
  356.  
  357. #declare macb11=union{
  358.     object{panel14 translate<-25,0,-25>}   
  359.     object{panel14 translate<25,0,-25>}   
  360.     object{panel14 rotate y*90 translate<-50,0,0>}
  361. }
  362. #declare planta4=union{
  363.     object{macb11}
  364.     object{macb11 rotate y*180}
  365. }
  366. #declare macb12=union{
  367.     object{panel5 translate<-25,0,-25>}   
  368.     object{panel5 translate<25,0,-25>}   
  369.     object{panel5 rotate y*90 translate<-50,0,0>}
  370. }
  371. #declare planta5=union{
  372.     object{macb12}
  373.     object{macb12 rotate y*180}
  374. }
  375. #declare macb13=union{
  376.     object{panel1 translate<-25,0,-25>}   
  377.     object{panel1 translate<25,0,-25>}   
  378.     object{panel1 rotate y*90 translate<-50,0,0>}
  379. }
  380. #declare planta6=union{
  381.     object{macb13}
  382.     object{macb13 rotate y*180}
  383. }
  384. #declare tejlat0=union{
  385.     object{mtej2 rotate y*90 translate <0,0,0>}
  386.     object{paneld4 rotate y*90 translate<-25,0,0>}   
  387.     object{paneld5 rotate y*-90 translate<25,0,0>}
  388. }
  389. #declare tejlat1=union{
  390.     object{mtej2 rotate y*90 translate <-25,0,0>}
  391.     object{mtej2 rotate y*90 translate <25,0,0>}
  392.     object{paneld4 rotate y*90 translate<-50,0,0>}   
  393.     object{paneld5 rotate y*-90 translate<50,0,0>}
  394. }
  395. // laterales de 2 pisos con escalera
  396. #declare lateral1_2=union{
  397.     object{escal5 translate<70,0,7.5> rotate y*180}
  398.     object{planta1 rotate y*180}
  399.     object{planta3 translate <0,50,0>}
  400.     object{tejlat1 translate<0,100,0>}
  401.     rotate y*180
  402. }    
  403. #declare lateral2_2=union{
  404.     object{escal52 translate<70,0,7.5> rotate y*180}
  405.     object{planta6 rotate y*180}
  406.     object{planta3 translate <0,50,0>}
  407.     object{tejlat1 translate<0,100,0>}
  408.     rotate y*180
  409. }    
  410. //laterales de 2 pisos sin escalera
  411. #declare lateral3_2=union{
  412.     object{planta2}
  413.     object{planta4 translate <0,50,0>}
  414.     object{tejlat1 translate<0,100,0>}    
  415. }    
  416. #declare lateral4_2=union{
  417.     object{planta3}
  418.     object{planta5 translate <0,50,0>}
  419.     object{tejlat1 translate<0,100,0>}    
  420. }    
  421. //laterales de un piso, sin puerta y 10 metros de largo
  422. #declare lateral1_1=union{
  423.     object{planta4}
  424.     object{tejlat1 translate<0,50,0> }
  425.     rotate y*180
  426. }
  427. #declare lateral2_1=union{
  428.     object{planta5}
  429.     object{tejlat1 translate<0,50,0>}
  430.     rotate y*180
  431. }
  432. // laterales de un piso y 5 metros de largo
  433. #declare lateral3_1=union{
  434.     object{panel14 translate<0,0,-25>}   
  435.     object{panel1 rotate y*90 translate<-25,0,0>}
  436.     object{panel1 rotate y*-90 translate<25,0,0>}
  437.     object{tejlat0 scale <0,.50,0> translate<0,51,0> rotate y*180}
  438. }    
  439. #declare lateral4_1=union{
  440.     object{panel5 translate<0,0,-25>}   
  441.     object{panel1 rotate y*90 translate<-25,0,0>}
  442.     object{panel1 rotate y*-90 translate<25,0,0>}
  443.     object{tejlat0 scale <0,.50,0> translate<0,51,0> rotate y*180}
  444. }    
  445. /*estructuras colgantes para casa grandes y torres. Son, ejem, las dos de
  446.   arriba mas el soporte */
  447. #declare colgante1=union{
  448.     object{lateral3_1 translate<0,60,0>}
  449.     object{soporte1 translate <0,0,-6.5> scale <1,1,1.7> translate <0,0,29>}
  450. }    
  451. #declare colgante2=union{
  452.     object{lateral4_1 translate<0,60,0>}
  453.     object{soporte1 translate <0,0,-6.5> scale <1,1,1.7> translate <0,0,29>}
  454. }    
  455. #declare colgante3=union{
  456.     object{colgante1 translate<-25,0,0>}
  457.     object{colgante1 translate<25,0,0>}
  458.     object{soporte1 translate <0,0,-6.5> scale <1,1,1.7> translate <-25,0,29>}
  459.     object{soporte1 translate <0,0,-6.5> scale <1,1,1.7> translate <25,0,29>}
  460. }    
  461. #declare colgante4=union{
  462.     object{colgante2 translate<-25,0,0>}
  463.     object{colgante2 translate<25,0,0>}
  464.     object{soporte1 translate <0,0,-6.5> scale <1,1,1.7> translate <-25,0,29>}
  465.     object{soporte1 translate <0,0,-6.5> scale <1,1,1.7> translate <25,0,29>}
  466. }    
  467.  
  468.  
  469. //Seguidamente creamos secciones para un par de torres cuadradas de 5 y 10
  470. //metros de lado, construidas ambas con paneles (Estas torres pueden usar
  471. //los soportes de las estructuras colgantes)
  472. //En primer lugar 4 secciones para torres de 5 metros
  473. #declare secbpan51=union{       //seccion base (puerta en -Z)
  474.     object{panel8 translate<0,0,-25>}   
  475.     object{panel5 translate<0,0,-25> rotate y*180}   
  476.     object{panel4 translate<0,0,-25> rotate y*90}
  477.     object{panel3 translate<0,0,-25> rotate y*-90}
  478. }
  479. #declare secmpan51=union{       //seccion media sin ventanas
  480.     object{panel1 translate<0,0,-25>}   
  481.     object{panel1 translate<0,0,-25> rotate y*180}   
  482.     object{panel4 translate<0,0,-25> rotate y*90}
  483.     object{panel4 translate<0,0,-25> rotate y*-90}
  484. }
  485. #declare secmpan52=union{       //seccion media con 4 ventanas
  486.     object{panel5 translate<0,0,-25>}   
  487.     object{panel5 translate<0,0,-25> rotate y*180}   
  488.     object{panel14 translate<0,0,-25> rotate y*90}
  489.     object{panel14 translate<0,0,-25> rotate y*-90}
  490. }
  491. #declare secmpan53=union{       //seccion media con una ventana
  492.     object{panel1 translate<0,0,-25>}   
  493.     object{panel2 translate<0,0,-25> rotate y*180}   
  494.     object{panel3 translate<0,0,-25> rotate y*90}
  495.     object{panel14 translate<0,0,-25> rotate y*-90}
  496. }
  497. //tejado piramidal
  498. #declare tejpir5=union{
  499.     object{paneld1 translate<0,0,-25>}
  500.     object{paneld1 translate<0,0,-25> rotate y*180}
  501.     object{tejado1 }
  502.     scale <1,1.30,1>
  503. }    
  504. //un ejemplo de torre (unos 12 metros de altura
  505. #declare torpan5_1=union{
  506.     object{secbpan51}
  507.     object{secmpan52 translate<0,50,0>}
  508.     object{secmpan51 translate<0,100,0> rotate y*90}
  509.     object{tejpir5 translate<0,150,0>}
  510. }    
  511. #declare torpan5_2=union{
  512.     object{secbpan51}
  513.     object{secmpan51 translate<0,50,0>}
  514.     object{secmpan52 translate<0,100,0>}
  515.     object{secmpan53 translate<0,150,0>}
  516.     object{tejpir5 translate<0,200,0>}
  517. }    
  518. #declare torpan5_3=union{
  519.     object{secbpan51}
  520.     object{secmpan53 translate<0,50,0>}
  521.     object{tejpir5 translate<0,100,0>}
  522. }
  523.  
  524. //tiras para las torres de 10 metros de lado
  525. #declare tira1_a=union{
  526.     object{panel1 translate<-25,0,0>}
  527.     object{panel1 translate<25,0,0>}
  528. }
  529. #declare tira2_a=union{
  530.     object{panel14 translate<-25,0,0>}
  531.     object{panel1 translate<25,0,0>}
  532. }
  533. #declare tira3_a=union{
  534.     object{panel12 translate<-25,0,0>}
  535.     object{panel2 translate<25,0,0>}
  536. }
  537. #declare tira4_a=union{
  538.     object{panel5 translate<-25,0,0>}
  539.     object{panel4 translate<25,0,0>}
  540. }
  541. #declare tira5_a=union{
  542.     object{panel2 translate<-25,0,0>}
  543.     object{panel3 translate<25,0,0>}
  544. }
  545. #declare tira6_a=union{
  546.     object{panel13 translate<-25,0,0>}
  547.     object{panel8 translate<25,0,0>}
  548. }
  549. #declare tira7_a=union{
  550.     object{panel5 translate<-25,0,0>}
  551.     object{panel5 translate<25,0,0>}
  552. }
  553. #declare tira8_a=union{
  554.     object{panel11 translate<-25,0,0>}
  555.     object{panel5 translate<25,0,0>}
  556. }
  557. #declare tira9_a=union{
  558.     object{panel1 translate<-25,0,0>}
  559.     object{panel4 translate<25,0,0>}
  560. }
  561.  
  562. // ahora 4 secciones para torres de 10 metros de lado
  563. #declare secbpan101=union{  //seccion base (puertas en +X y +Z)
  564.     object{tira4_a translate<0,0,-50>}
  565.     object{tira6_a translate<0,0,-50> rotate y*90}   
  566.     object{tira8_a translate<0,0,-50> rotate y*180}
  567.     object{tira2_a translate<0,0,-50> rotate y*-90}
  568. }
  569. #declare secmpan101=union{       //2 lados sin ventanas y otro con
  570.     object{tira9_a translate<0,0,-50>}
  571.     object{tira9_a translate<0,0,-50> rotate y*90}
  572.     object{tira7_a translate<0,0,-50> rotate y*-90}
  573.     object{tira7_a translate<0,0,-50> rotate y*180}
  574. }
  575. #declare secmpan102=union{       //una sola ventana
  576.     object{tira1_a translate<0,0,-50>}
  577.     object{tira5_a translate<0,0,-50> rotate y*90}
  578.     object{tira9_a translate<0,0,-50> rotate y*-90}
  579.     object{tira2_a translate<0,0,-50> rotate y*180}
  580. }
  581. #declare secmpan103=union{       //un lado sin ventanas y otro con
  582.     object{tira1_a translate<0,0,-50>}
  583.     object{tira1_a translate<0,0,-50> rotate y*90}
  584.     object{tira2_a translate<0,0,-50> rotate y*-90}
  585.     object{tira2_a translate<0,0,-50> rotate y*180}
  586. }
  587.  
  588. #declare tejado2=union{
  589.     object{mtej2 rotate y*-90 translate <0,0,-25>}
  590.     object{mtej2 rotate y*-90 translate <0,0,-25> rotate y*180}
  591.     texture{tejas}
  592. }    
  593. #declare tejpir10=union{
  594.     object{tejado2 translate<-25,0,0>}
  595.     object{tejado2 translate<25,0,0>}
  596.     object{paneld6 rotate y*90 translate <-50,0,0>}
  597.     object{paneld6 rotate y*-90 translate <50,0,0>}
  598.     scale <1,1.30,1>
  599. }
  600. #declare torpan10_1=union{      //torre de 27 metros 
  601.     object{secbpan101}
  602.     object{secmpan101 translate<0,50,0>}
  603.     object{secmpan103 translate<0,100,0>}
  604.     object{secmpan101 translate<0,150,0>}
  605.     object{tejpir10 translate<0,200,0>}
  606.     object{torpan5_1 translate<0,0,-60>}
  607.     object{torpan5_1 rotate y*90 translate<0,0,-50> rotate y*90}
  608.     object{torpan5_1 rotate y*90 translate<0,0,-50> rotate y*-90}
  609.     object{torpan5_1 translate<0,0,-60> rotate y*180}
  610. }    
  611. #declare torpan10_2=union{      //torre de 27 metros con colgantes 
  612.     object{secbpan101}
  613.     object{secmpan101 translate<0,50,0>}
  614.     object{secmpan103 translate<0,100,0>}
  615.     object{colgante1 translate<0,50,-50>}
  616.     object{colgante2 translate<0,50,-50> rotate y*90}
  617.     object{colgante2 translate<0,50,-50> rotate y*-90}
  618.     object{colgante1 translate<0,50,-50> rotate y*180}
  619.     object{secmpan101 translate<0,150,0>}
  620.     object{tejpir10 translate<0,200,0>}
  621. }    
  622.  
  623.  
  624.  
  625.